source: trunk/debathena/debathena/xsession/debian/xsession.tcsh @ 23852

Revision 23852, 1.4 KB checked in by broder, 15 years ago (diff)
In xsession: * Don't let people set debathena-nocalls as their default session. * Don't source .startup.X if NOCALLS is set.
  • Property svn:executable set to *
Line 
1#!/usr/bin/tcsh -f
2
3# This is the Athena xsession wrapper for tcsh users.  Its job is to:
4# 1. Set the XSESSION environment variable.
5# 2. Process the user's dotfiles including .environment.
6# 3. Run standard startup programs if the user has not opted out.
7# 4. Run the user's .startup.X.
8
9set initdir=/usr/lib/init
10
11setenv XSESSION $$
12
13if (-r /etc/.login) source /etc/.login
14if (-r /etc/.cshrc) source /etc/.cshrc
15if (-r /etc/csh.login) source /etc/csh.login
16if (-r /etc/csh.cshrc) source /etc/csh.cshrc
17
18if (-r ~/.cshrc) then
19  source ~/.cshrc
20else
21  if (-r ${initdir}/cshrc) source ${initdir}/cshrc
22endif
23
24if (! $?skip_initial_xterm) then
25  setenv ATHENA_INITIAL_X_TERMINAL
26endif
27
28if (! $?skip_x_startup) then
29  if (! $?ZEPHYR_CLIENT) setenv ZEPHYR_CLIENT zwgc
30  $ZEPHYR_CLIENT
31  ($initdir/displaymotd &)
32  if (! $?skip_quotawarn) then
33    ($initdir/quotawarn &)      # Display warning dialogs if near quota
34  endif
35  if (! $?skip_authwatch) then
36    (authwatch &)
37  endif
38endif
39
40if (! $?skip_lert) then
41  ($initdir/displaylert &)
42endif
43
44if (-r ~/.startup.X && (! $?NOCALLS)) then
45  (source ~/.startup.X &)
46endif
47
48# If we got this far, then there were no errors that the user /really/
49# needed to see, so get rid of the ugly xterm
50if ( "$DEBATHENA_HOME_TYPE" == "afs" && $?XCONSOLE ) then
51    kill $XCONSOLE
52    unsetenv XCONSOLE
53endif
54
55# Proceed with the session command, which has been passed as arguments.
56exec $argv:q
Note: See TracBrowser for help on using the repository browser.